LocalizaçãoEste batch gera um arquivo HTML que contém explicações de cada comando.
Copie o código abaixo, cole num editor de textos e salve com a extensão .BAT
Autor: B
SS-HEAD
Este script não foi alterado!
Copie o código abaixo, cole num editor de textos e salve com a extensão .BAT
- Código:
@ECHO OFF
REM.-- Preparando o processador de comandos
SETLOCAL ENABLEEXTENSIONS
SET "versao=01.000" &:20051201 p.h. Versão original, origem http://batch-satti.forumeiros.com
SET "versao=01.001" &:20060122 p.h. Fixar exclamações ausente no documento (http://batch-satti.forumeiros.com)
SET "versao=01.002" &:20060218 p.h. Substituído AREADETEXTO com PRE XMP (http://batch-satti.forumeiros.com)
SET "versao=01.003" &:20060218 p.h. php incorporado (http://batch-satti.forumeiros.com)
SET "versao=01.004" &:20060723 p.h. Afixar página para FireFox (http://batch-satti.forumeiros.com)
SET "versao=01.005" &:20061015 p.h. Chamar AJUDA via '"call ajuda" ,permitindo ajudar comando com um ficheiro help.bat (http://batch-satti.forumeiros.com)
SET "versao=01.006" &:20061015 p.h. Iniciando indicador de progresso (http://batch-satti.forumeiros.com)
SET "versao=01.007" &:20080316 p.h. usar codepage 1252 suporte utilizadores europeu (http://batch-satti.forumeiros.com)
SET "versao=02.000" &:20080316 p.h. usar comando FOR gerar HTML , evita a perda de carácteres (http://batch-satti.forumeiros.com)
SET "versao=%versao: =%"
for /f "delims=: tokens=2" %%a in ('chcp') do set "restore_codepage=%%a"
chcp 1252>NUL
set "z=%~dpn0.htm"
echo.^<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.0 Transitional//BR"^> >"%z%"
set "title=Tutorial de Comandos Ms-DOS"
set "title2=BSS-HEAD"
for /f "tokens=*" %%a in ('ver') do set "winver=%%a"
echo.Criando arquivo ...
for %%A in (
""
"<html><title>%title%</title>"
"<BODY BGCOLOR=#66FFCC TEXT=#000000 LINK=#0000FF ALINK=#FFFF00 VLINK=#FF0066>"
"<BODY BGCOLOR=#66FF99 TEXT=#000000 LINK=#0000FF ALINK=#FFFF00 VLINK=#FF0066>"
"<BODY BGCOLOR=#33FFCC TEXT=#000000 LINK=#0000FF ALINK=#FFFF00 VLINK=#FF0066>"
"<BODY BGCOLOR=#00FFCC TEXT=#000000 LINK=#0000FF ALINK=#FFFF00 VLINK=#FF0066>"
"<BODY BGCOLOR=#00FF99 TEXT=#000000 LINK=#0000FF ALINK=#FFFF00 VLINK=#FF0066>"
"<font color='darkblue'>"
"<center>"
"<h1>%title%</h1>"
"</center>"
"<font color='red'>"
"<p><i><a href="http://batch-satti.forumeiros.com" title="%title2%">%title2%</a></i></p>"
"<font color='darkblue'>"
"<center>"
"<table border=1 cellspacing=1 cellpadding=3>"
" <tr><td>Versão do Windows</td><td>:</td><td>%winver%</td></tr>"
" <tr><td>Arquivo fonte</td><td>:</td><td><a href='http://batch-satti.forumeiros.com/entrar-no-forum-f1/tutorial-batch-html-t64.htm#231'>"
" <b>Batch-Satti Site de programação Batch </b></a></td></tr>"
" <tr><td>Criado por</td><td>:</td><td><a href='http://batch-satti.forumeiros.com/entrar-no-forum-f1/somente-para-quem-e-membro-se-voce-ainda-nao-e-membrocadastre-se-para-ter-acesso-a-esses-scripts-t35.htm'>"
" <b>%title2% do forum Batch-Satti </b></a><br><a href=#%~n0><b>Código fonte deste script logo abaixo</b></a></td></tr>"
"</table>"
"<br><br>"
"<table>"
) do echo.%%~A>>"%z%"
echo.Criando indice ...
set /a cnt=0
for /f "tokens=1,*" %%a in ('"help|findstr /v /b /c:" " /c:"For more""') do (
for %%A in (
" <tr><td><a href='#%%a'>%%a</a></td><td>%%b</td></tr>"
) do echo.%%~A>>"%z%"
set /a cnt+=1
)
for %%A in (
"</table>"
"<br><br>"
"</center>"
) do echo.%%~A>>"%z%"
echo.Extraindo texto de ajuda ...
call:initProgress cnt
for /f %%a in ('"help|findstr /v /b /c:" " /c:"For more""') do (
echo.Precessando %%a
for %%A in (
"<div style='float: right'><a href='#'>TOPO</a></div>"
"<center><h2><a name='%%a'>%%a</a></h2></center>"
"<div style='background: #F8F8FF'><pre><xmp>"
) do echo.%%~A>>"%z%"
call help %%a >>"%z%" 2>&1
echo ^</xmp^> >>"%z%"
for %%A in (
"</pre></div>"
) do echo.%%~A>>"%z%"
call:tickProgress
)
echo.Adicionando c¢digo do arquivo ...
for %%A in (
""
"<left>"
"<br><br>"
"<div style='float: right'><a href='#'>TOPO</a></div>"
"<a name='%~n0'><h2>O codigo de Indice Comandos Ms-DOS </h2></a>"
"Este %title% Foi criado automaticámente pelo fonte abaixo:"
"<br><br>"
"</left>"
"<div style='background: #000000; color: #FFFFFF;'><pre><xmp>"
) do echo.%%~A>>"%z%"
type "%~f0" >>"%z%"
echo.Criando rodap‚ ...
echo ^</xmp^> >>"%z%"
for %%A in (
"</pre></div>"
"</left>"
""
"</font>"
"</body>"
"</html>"
) do echo.%%~A>>"%z%"
chcp %restore_codepage%>NUL
explorer "%z%"
:SKIP
REM.-- Final da aplicativo
FOR /l %%a in (5,-1,1) do (TITLE %title% -- Fechando in %%as&ping -n 2 -w 1 127.0.0.1>NUL)
TITLE Pressione qualquer tecla para encerrar&ECHO.&GOTO:EOF
:initProgress
set /a "ProgressCnt=-1"
set /a "ProgressMax=%~1"
set "ProgressFormat=%~2"
if "%ProgressFormat%"=="" set "ProgressFormat=[PPPP]"
set "ProgressFormat=%ProgressFormat:[PPPP]=[P] completado.%"
call :tickProgress
GOTO:EOF
:tickProgress
set /a "ProgressCnt+=1"
SETLOCAL
set /a "per=100*ProgressCnt/ProgressMax"
set "per=%per%%%"
call title %%ProgressFormat:[P]=%per%%%
GOTO:EOF
Autor: B
SS-HEADEste script não foi alterado!
» Hack pack + Name hack
» Íkarus versão 2 > em breve
» Ikarus RG3NET
» Game Zone De Volta
» Habbo Zuera !
» Mega Hack - - não funfa mais
» Versão 2 Ikarus!
» HABBIG ( ADM: GAME ZONE )